REPORT z_modified_sap_objects LINE-SIZE 124 NO STANDARD PAGE HEADING.

*** TABLES ***
TABLES: smodilog.


*** INTERNAL TABLES ***
DATA: BEGIN OF v_smodilog,
        obj_type TYPE smodilog-obj_type,
        obj_name TYPE smodilog-obj_name,
        operation TYPE smodilog-operation,
        mod_user TYPE smodilog-mod_user,
        mod_date TYPE smodilog-mod_date,
        mod_time TYPE smodilog-mod_time,
        trkorr TYPE smodilog-trkorr,
        spau_code TYPE smodilog-spau_code,
      END OF v_smodilog.

DATA: i_smodilog LIKE STANDARD TABLE OF v_smodilog.


*** SELECTION SCREEN ***
SELECT-OPTIONS: s_type FOR smodilog-obj_type.



***********************************************************************
***
*** PROCESSING START
***
***********************************************************************



*---------------------------------------------------------------------*
* START-OF-SELECTION
*---------------------------------------------------------------------*
START-OF-SELECTION.

  PERFORM get_mods.

  PERFORM write_list.

  ULINE.


*---------------------------------------------------------------------*
* TOP-OF-PAGE
*---------------------------------------------------------------------*
TOP-OF-PAGE.

  PERFORM write_heading.



***********************************************************************
***
*** DATABASE METHODS
***
***********************************************************************



*---------------------------------------------------------------------*
*       FORM get_mods
*---------------------------------------------------------------------*
* Gets the list of modifications from the database.
*---------------------------------------------------------------------*
FORM get_mods.

  SELECT obj_type
         obj_name
         operation
         mod_user
         mod_date
         mod_time
         trkorr
         spau_code
    FROM smodilog
    INTO TABLE i_smodilog
   WHERE obj_type IN s_type
     AND ( operation = 'PRE'
        OR operation = 'POST'
        OR operation = 'ALL'
        OR operation = 'NEW'
        OR operation = 'REPA'
        OR operation = 'IMP'
        OR operation = 'MOD'
        OR operation = 'ORIG' ).

  SORT i_smodilog BY obj_type obj_name mod_date mod_time.

ENDFORM.                    "get_mods



***********************************************************************
***
*** OUTPUT DISPLAY METHODS
***
***********************************************************************



*---------------------------------------------------------------------*
*       FORM write_list
*---------------------------------------------------------------------*
* Writes the results list to the screen.
*---------------------------------------------------------------------*
FORM write_list.

  LOOP AT i_smodilog INTO v_smodilog.

    WRITE: /                          '|',
           (4)  v_smodilog-obj_type,  '|',
           (40) v_smodilog-obj_name,  '|',
           (4)  v_smodilog-operation, '|',
           (12) v_smodilog-mod_user,  '|',
           (10) v_smodilog-mod_date,  '|',
           (8)  v_smodilog-mod_time,  '|',
           (20) v_smodilog-trkorr,    '|',
           (1)  v_smodilog-spau_code, '|'.

  ENDLOOP.

ENDFORM.                    "write_list


*---------------------------------------------------------------------*
*       FORM write_heading
*---------------------------------------------------------------------*
* Writes the column headings to the screen.
*---------------------------------------------------------------------*
FORM write_heading.

  ULINE.

  WRITE: /                          '|',
         (4)  'Type'      CENTERED, '|',
         (40) 'Object'    CENTERED, '|',
         (4)  'Oper'      CENTERED, '|',
         (12) 'User'      CENTERED, '|',
         (10) 'Date'      CENTERED, '|',
         (8)  'Time'      CENTERED, '|',
         (20) 'Transport' CENTERED, '|',
         (1)  'S'         CENTERED, '|'.

  ULINE.

ENDFORM.                    "write_heading